【全服过滤】动态界面脚本，可保存状态，可恢复状态

hswd · 发表于 2024-7-16 12:38:07

QM人物上线 CALL @ScriptLogin
QF 功能 CALL @ScriptEntry

[@FilterInit]
{
#if
#act
GetListVarCount L$按钮状态 P0
#if
EQUAL P0 0
#act
MOV L$按钮状态 <$STR(T90)>
#if
#act
MOV L$屏蔽信息 [屏蔽提示,屏蔽全局,屏蔽系统,屏蔽滚动]
MOV L$解除信息 [解除提示,解除全局,解除系统,解除滚动]
MOV N$按钮数量 4
MOV N$按钮下标 0
MOV N$默认状态 0
LoopGoto @FilterButtonInit <$STR(N$按钮数量)>
[@FilterButtonInit]
#if
#act
MOV S$FilterButton<$STR(N$按钮下标)> <<$STR(L$屏蔽信息[<$STR(N$按钮下标)>])>/@OnFilterButton(<$STR(N$按钮下标)>,1,9)>
#if
#act
INC N$按钮下标 1
}
[@ScriptLogin]
{
#if
#act
#CALLEx [..\QuestDiary\游戏功能\综合服务.txt] @FilterInit
#CALLEx [..\QuestDiary\游戏功能\综合服务.txt] @ResetFilterButton
}
[@ScriptEntry]
{
#if
#act
#CALLEx [..\QuestDiary\游戏功能\综合服务.txt] @FilterInit
#CALLEx [..\QuestDiary\游戏功能\综合服务.txt] @ResetFilterButton
#CALLEx [..\QuestDiary\游戏功能\综合服务.txt] @FilterMain
}
[@FilterMain]
{
#if
#act
CLOSEMERCHANTBIGDLG
MOV T90 <$STR(L$按钮状态)>
#say
;<清空变量/@清空>\
<╔┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈╗/SCOLOR=13>\
<╠--------------------------------------------------------╣/SCOLOR=13>\
<┊/SCOLOR=13> <$STR(S$FilterButton0)> <$STR(S$FilterButton1)> <$STR(S$FilterButton2)> <┊/SCOLOR=13>\
<╠--------------------------------------------------------╣/SCOLOR=13>\
<┊/SCOLOR=13> <$STR(S$FilterButton3)> <┊/SCOLOR=13>\
<╚┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈┈╝/SCOLOR=13>\
[@清空]
#if
#act
MOV T90
MOV L$按钮状态
[@OnFilterButton]
#if
#act
MOV N$按钮下标 <$SCRIPTPARAM1>
MOV N$按钮状态 <$SCRIPTPARAM2>
#if
large N$按钮状态 1
small N$按钮状态 0
#act
SENDMSG 6 非法的参数1
break
#if
#act
SendMsg 6 Index:<$STR(N$按钮下标)>,State:<$STR(N$按钮状态)>
#if
CHECKSCRIPTPARAM <$STR(N$按钮下标)>,0,9
#act
RemoveListByContent L$按钮状态 <$STR(N$按钮下标)>
MOV S$FilterButton<$STR(N$按钮下标)> <<$STR(L$屏蔽信息[<$STR(N$按钮下标)>])>/@OnFilterButton(<$STR(N$按钮下标)>,1,9)>
#if
CHECKSCRIPTPARAM <$STR(N$按钮下标)>,1,9
#act
AddToList L$按钮状态 <$STR(N$按钮下标)>
MOV S$FilterButton<$STR(N$按钮下标)> <<$STR(L$解除信息[<$STR(N$按钮下标)>])>/@OnFilterButton(<$STR(N$按钮下标)>,0,9)>
#if
#act
GOTO @OnFilterButtonEvent(<$STR(N$按钮下标)>,<$STR(N$按钮状态)>)
GOTO @FilterMain
[@OnFilterButtonEvent]
#if
#act
MOV N$按钮下标 <$SCRIPTPARAM1>
MOV N$按钮状态 <$SCRIPTPARAM2>
#if
#act
MOV N$屏蔽类型 <$STR(N$按钮下标)>
INC N$屏蔽类型 1
#if
#act
;SendMsg 6 屏蔽类型：<$STR(N$屏蔽类型)>，屏蔽状态：<$STR(N$按钮状态)>
#if
SMALL N$按钮下标 5
#act
FilterGlobalMsg <$STR(N$屏蔽类型)> <$STR(N$按钮状态)>
break
}
[@ResetFilterButton]
{
#if
#act
MOV N$按钮下标 0
LoopGoto @ResetFilterButtonLoop <$STR(N$按钮数量)>
[@ResetFilterButtonLoop]
#if
#act
MOV N$屏蔽类型 <$STR(N$按钮下标)>
INC N$屏蔽类型 1
#if
CheckVarInList L$按钮状态 <$STR(N$按钮下标)>
#act
MOV S$FilterButton<$STR(N$按钮下标)> <<$STR(L$解除信息[<$STR(N$按钮下标)>])>/@OnFilterButton(<$STR(N$按钮下标)>,0,9)>
FilterGlobalMsg <$STR(N$屏蔽类型)> 1
SendMsg 5 恢复按钮：<$STR(N$按钮下标)>
#if
#act
INC N$按钮下标 1
}